Sounds like it's failing on the AES/SSL checks - it will do that about between every 1-2 minutes.
You can fix it with this code - you're probably missing the certificate chain file.
(plays fine for me)
Sub Main()
port=CreateObject("roMessagePort")
screen=CreateObject("roVideoScreen")
screen.SetMessagePort(port)
z=CreateObject("roAssociativeArray")
z.Title="Live Feed"
z.StreamFormat="hls"
z.Live=true
screen.SetCertificatesFile("common:/certs/ca-bundle.crt")
screen.InitClientCertificates()
z.streams=[
{ url : "https://sslhls.m6tv.cdn.sfr.net/hls-live/livepkgr/_definst_/w9_hls_aes/w9_hls_aes_856.m3u8",
bitrate : 0,
quality : false
}
]
screen.SetContent(z)
screen.Show()
While TRUE
msg=Wait(0,port)
If Type(msg)="roVideoScreenEvent"
If msg.isRequestFailed()
Print"MSG = ";msg.getMessage()
Print"INDEX = ";msg.GetIndex()
Print"TYPE = ";msg.GetType()
Print"DATA = ";msg.GetData()
Print"INFO = ";msg.GetInfo()
Else If msg.isStatusMessage()
Print"Video status: ";msg.GetIndex();" ";msg.GetData()
Else If msg.isButtonPressed()
Print"Button pressed: ";msg.GetIndex();" ";msg.GetData()
Else If msg.isStreamSegmentInfo()
Else If msg.isDownloadSegmentInfo()
Else If msg.isStreamStarted()
Else If msg.isPaused()
Else If msg.isResumed()
Else If msg.isScreenClosed()
Exit While
Else
Print"Unexpected event type: ";msg.GetType()
End If
Else
Print"Unexpected message class: ";Type(msg)
End If
End While
End Sub
(edited to add more msg types to eliminate unexpected event messages)
