roVideoPlayer SetContentList function not working

Question

This may seem like a super basic question, but I just can't figure it out! 😂

One the app I am creating I am using a basic Video xml element to play a given video, however I need to be able to check to see if I get a 404 when trying to play a video. The problem lies in the fact that the Video object will just repeatedly request a video from my server even if it only gets 404s back.

So, I decided to swap to a `roVideoPlayer` object instead since it gives me more control and can hopefully tell me what the response code of the given video is, that way I can have the player stop playing and display an error message if it gets a 404. The problem is that I just CAN NOT get the `SetContentList` function working! No matter how many different combinations of arrays, associative arrays, etc. I try, it just tells me that "Interface not a member of BrightScript Component". I've checked the 3+ sources of documentation and scoured the forum, but I just can't figure it out. As far as I know, it's supposed to be an array of `roAssociativeArray`s, and each associative array contains the details of a video to be played.

My code has been multiple different variations of this, but never works:

```video = { Title: "Video Title", Stream: { url: videoUrl }, StreamFormat: "mp4" } videoPlayer.SetContentList([video])```

Alternatively, if there is a way to check if a Video SceneGraph element fails to play a video due to a 404 error being returned from the server, that would solve the original problem.

Thank you for your help 🙂

RokuKC · Answer

Roku SceneGraph is the recommended development platform, and there the Video node should be used.https://developer.roku.com/docs/developer-program/core-concepts/core-concepts.mdhttps://developer.roku.com/docs/developer-program/core-concepts/playing-videos.mdOtherwise, as far as I know, roVideoPlayer is still supported for roScreen / 2D UI only.&nbsp;(The deprecation notice has been there for many many years, but I believe it does not apply in that limited/unusual situation, but rather was intended to guide streaming channel developers to transition to SceneGraph.)&nbsp;

renojim · Answer

That's for a Video node.&nbsp; My "onState" observer function fires first with "buffering" and then with "error" when I set the URL to a nonexistent file.&nbsp; I've also used observers with message ports and waited on the port in the main thread.&nbsp; That looks something like this:Function displayVideo(video as Object) as Integer
    print "Displaying video: "; video["url"]

vn = m.video_node
    vc = createObject("roSGNode", "ContentNode")
    vc.url = video.url
    vc.StreamFormat = video.StreamFormat
    print vn.observeField("position", m.port)
    print vn.observeField("control", m.port)
    print vn.observeField("state", m.port)

vn.content = vc
    vn.setFocus(true)
    vn.control = "play"
    while true
        msg = wait(0,m.port)
        msgtype = type(msg)
        print msgtype
        if msgtype = "roSGNodeEvent" then
            node = msg.GetNode()
            field = msg.GetField()
            data = msg.GetData()
            print node, field, data
            if field = "position" then
                position = data
            else if field = "control" and data = "stop" then
                exit while
            else if field = "state" then
                if data = "finished" then
                    exit while
                else if data = "buffering" then
                    m.video_screen.visible = true
                else if data = "error" then
                    print vn.errorCode
                    print vn.errorMsg
                    print vn.errorStr
                    print vn.errorInfo
                else if data = "playing" then
                   '
                else if data = "paused" then
                   '
                end if
            end if
        else if msgtype = "roSGScreenEvent" then
            print msgtype, msg.GetData(), msg.isScreenClosed()
            vn.control = "stop"
            exit while
        end if
    end while
    vn.control = "stop"
    print vn.unobserveField("position")
    print vn.unobserveField("control")
    print vn.unobserveField("state")
    return position
End Function&nbsp;and produces this output:roSGNodeEvent
video           control         play
roSGNodeEvent
video           state           buffering
roSGNodeEvent
video           state           error
errorCode:  -1
errorMsg:  There was an error in the HTTP response.  This could mean that malformed HTTP headers or an HTTP error code was returned.
errorStr:  reader pick stream error:HTTP error:HTTP server returned error code:404:extra:etype:buffer
errorInfo:  &lt;Component: roAssociativeArray&gt; =
{
    category: "http"
    clipid: 1
    dbgmsg: "reader pick stream error:HTTP error:HTTP server returned error code:404:extra:etype:buffer"
    drmerrcode: 0
    errcode: 2
    ignored: false
    source: "buffer:reader"
}

renojim · Answer

I don't know how much time you want to spend on roVideoPlayer.&nbsp; When I just tried to use it I got, "BRIGHTSCRIPT: WARNING: roVideoPlayer: This component is deprecated".&nbsp; I don't see that mentioned in the documentation for roVideoPlayer, but it is mentioned here.&nbsp; If you want to experiment, this works for me: player = CreateObject("roVideoPlayer")
 player.SetContentList([{
     Stream: { url: "http://192.168.0.118/1.mp4" }
     StreamFormat: "mp4"
 },{
     Stream: { url: "http://192.168.0.118/2.mp4" }
     StreamFormat: "mp4"
 },{
     Stream: { url: "http://192.168.0.118/3.mp4" }
     StreamFormat: "mp4"
 },{
     Stream: { url: "http://192.168.0.118/4.mp4" }
     StreamFormat: "mp4"
 },{
     Stream: { url: "http://192.168.0.118/5.mp4" }
     StreamFormat: "mp4"
 }])
 player.SetMessagePort(m.port)
 player.SetLoop(true)
 player.SetPositionNotificationPeriod(1)

player.Play()
 while true
     msg = wait(0, m.port)
     if msg &lt;&gt; invalid then
         print type(msg),msg.GetType(); ","; msg.GetIndex(); ": "; msg.GetMessage()
     end if
 end while&nbsp;

renojim · Answer

Is there a reason why you're using SetContentList and not just SetContent?For a video node, do you have an observer on the "state" of the video node?&nbsp; It should fire on any error.

Helaman · Answer

SetContentList is the function mentioned in the documentation, although I have tried SetContent. In terms of observing the state of the Video player, I can observe that it is buffering, playing, paused, etc. my problem is that I can't detect if its getting a 404 when trying to buffer a non-existent video.

Thank you for help btw

Forum Discussion

roVideoPlayer SetContentList function not working

9 Replies

Recent Discussions

DoRecovery API

Developing a personal/private media player

Anyone experiencing trouble adding new products?

Consumable Product?

Bif file creator